#!/usr/local/bin/gawk -f
#
#  primecube.awk 
#                                   by F. Poyo
#                    v.1.0  -- Sep. 25, 1996
#
#  This awk-script outputs a prime order magic cube. Run this by
#
#          gawk -f primecube.awk
#
#  Then, type the order. For example, if you type 7, the script
#  outputs 7x7x7 magic cube. The number must be prime number.
#  The number must be larger than 6.
#
BEGIN{no_solution=0;printf("The order must be a prime number (>6).\n");
      printf("Input the order N:");}
{N=$0;
  checkN();
  makecube();
  exit(0);
}
/end/{exit(0);}
END{
  if(no_solution!=1) {
    check_cube();
    printcube();
  }
}
#
function cleancube(i,j,k) {
   for(i=0;i<N;i++) {
     for(j=0;j<N;j++) {
       for(k=0;k<N;k++) {
         M[i,j,k]=0;
       }
     }
   }
}
#
function knight(n,i,j,k) {
  if(n==NNN+1) return;
  if(M[(i+mx)%N,j,(k+my)%N]==0) {
    i=(i+mx)%N;k=(k+my)%N;M[i,j,k]=n;n++; knight(n,i,j,k);}
  else {
    if(M[(i+1)%N,(j+mx)%N,(k+mx)%N]==0) {
      i=(i+1)%N; j=(j+mx)%N; k=(k+mx)%N; M[i,j,k]=n;n++; knight(n,i,j,k);}
    else {
      if(M[(i+1)%N,j,k]==0) {
         i=(i+1)%N; M[i,j,k]=n;n++; knight(n,i,j,k);}
      else {
         print "Unsucseeded(",n,")";
      }
    }
  }
}
#
function makecube(i,j,k,tmp) {
  cleancube();
  NNN=N*N*N;
  i=0;j=0;k=0;n=1;
  M[i,j,k]=n;n++;
#  m=int(N/2);
#  (mx,my) can be some of combinations of the numbers in (1,...,m).
  mx=2; my=1;
#
  knight(n,i,j,k);
}
#
function printcube(i,j,k) {
   for(i=0;i<N;i++) {
     printf("-------- Floor %d ------\n",i+1);
     for(j=0;j<N;j++) {
       for(k=0;k<N;k++) {
         printf("%4d ",M[i,j,k]);
       }
       printf("\n");
     }
     printf("-------------------------\n");
   }
}
#
function check_cube(i,j,k,sum,sum1,sum2,sum3,sumd1,sumd2,sumd3,sumd4) {
  sum=N*(NNN+1)/2;
  printf("sum=%d\n",sum);
  sumd1=0; sumd2=0; sumd3=0; sumd4=0;
  for(i=0;i<N;i++) {
    sumd1 += M[    i,    i,i];
    sumd2 += M[    i,N-i-1,i];
    sumd3 += M[N-i-1,    i,i];
    sumd4 += M[N-i-1,N-i-1,i];
    for(j=0;j<N;j++) {
      sum1=0;sum2=0;sum3=0;
      for(k=0;k<N;k++) {
        sum1+=M[k,i,j];
        sum2+=M[j,k,i];
        sum3+=M[i,j,k];
      }
      if(sum1 != sum) {printf( "sum1(*,%d,%d)=%d\n",i,j,sum1);}
      if(sum2 != sum) {printf( "sum2(%d,*,%d)=%d\n",j,i,sum2);}
      if(sum3 != sum) {printf( "sum3(%d,%d,*)=%d\n",i,j,sum3);}
    }
  }
  if(sumd1 != sum) {printf( "sumd1(+,+,+)=%d\n",sumd1);}
  if(sumd2 != sum) {printf( "sumd2(+,-,+)=%d\n",sumd2);}
  if(sumd3 != sum) {printf( "sumd3(-,+,+)=%d\n",sumd3);}
  if(sumd4 != sum) {printf( "sumd4(-,-,+)=%d\n",sumd4);}
}
#
function checkN(i) {
   if(N<7) {
       printf("Sorry, the number must be greater than 6.\n");
       no_solution=1;
       exit(0);
   }
   for(i=2;i<N;i++) {
     if(N%i==0) {
         printf("Sorry the order needs to be a prime number.\n");
         no_solution=1;
         exit(0);
     }
  }
}